c
c
c =========================================================
      subroutine rp1(maxmx,meqn,mwaves,mbc,mx,ql,qr,auxl,auxr,
     &		 wave,s,amdq,apdq)
c =========================================================
c
c     # solve Riemann problems for the 1D isothermal equations using Roe's 
c     # approximate Riemann solver.  
c
c     # On input, ql contains the state vector at the left edge of each cell
c     #           qr contains the state vector at the right edge of each cell
c     # On output, wave contains the waves,
c     #            s the speeds,
c     #            amdq the  left-going flux difference  A^- \Delta q
c     #            apdq the right-going flux difference  A^+ \Delta q
c
c     # Note that the i'th Riemann problem has left state qr(i-1,:)
c     #                                    and right state ql(i,:)
c     # From the basic clawpack routine step1, rp is called with ql = qr = q.
c
c
      implicit double precision (a-h,o-z)
      dimension   ql(1-mbc:maxmx+mbc, meqn)
      dimension   qr(1-mbc:maxmx+mbc, meqn)
      dimension    s(1-mbc:maxmx+mbc, mwaves)
      dimension wave(1-mbc:maxmx+mbc, meqn, mwaves)
      dimension amdq(1-mbc:maxmx+mbc, meqn)
      dimension apdq(1-mbc:maxmx+mbc, meqn)

c
c     # local storage
c     ---------------
      dimension delta(2)
      logical efix
      common /comrp/ aa   !# sound speed 
c
      data efix /.true./    !# use entropy fix for transonic rarefactions
c
c
      do 30 i=2-mbc,mx+mbc
c
c        # Compute Roe-averaged velocity:
	 rhsql = dsqrt(qr(i-1,1))
	 rhsqr = dsqrt(ql(i,1))
	 uave = (qr(i-1,2)/rhsql + ql(i,2)/rhsqr) / (rhsql+rhsqr)
c
c        # find a1 thru a3, the coefficients of the 3 eigenvectors:
c
         delta(1) = ql(i,1) - qr(i-1,1)
         delta(2) = ql(i,2) - qr(i-1,2)
	 a1 = ((uave+aa) * delta(1) - delta(2)) / (2.d0*aa)
	 a2 = -((uave-aa) * delta(1) - delta(2)) / (2.d0*aa)
c
c        # Compute the waves.
c
         wave(i,1,1) = a1
         wave(i,2,1) = a1*(uave-aa)
         s(i,1) = uave-aa
c
         wave(i,1,2) = a2
         wave(i,2,2) = a2*(uave+aa)
         s(i,2) = uave+aa
c
   30    continue
c
c
c     # compute flux differences
c     --------------------------
c
c
      if (efix) go to 110
c
c     # no entropy fix
c     ----------------
c
c     # amdq = SUM s*wave   over left-going waves
c     # apdq = SUM s*wave   over right-going waves
c
      do 100 m=1,meqn
         do 100 i=2-mbc, mx+mbc
            amdq(i,m) = 0.d0
            apdq(i,m) = 0.d0
            do 90 mw=1,mwaves
               if (s(i,mw) .lt. 0.d0) then
                   amdq(i,m) = amdq(i,m) + s(i,mw)*wave(i,m,mw)
                 else
                   apdq(i,m) = apdq(i,m) + s(i,mw)*wave(i,m,mw)
                 endif
   90          continue
  100       continue
      go to 900
c
c-----------------------------------------------------
c
  110 continue
c
c     # With entropy fix
c     ------------------
c
c    # compute flux differences amdq and apdq.
c    # First compute amdq as sum of s*wave for left going waves.
c    # Incorporate entropy fix by adding a modified fraction of wave
c    # if s should change sign.
c
c
      do 200 i=2-mbc,mx+mbc
c
c        # check 1-wave:
c        ---------------
c
	 s0 = qr(i-1,2)/qr(i-1,1) - aa  !# u-c in left state

c        # check for fully supersonic case:
	 if (s0.ge.0.d0 .and. s(i,1).gt.0.d0) then
c            # everything is right-going
             do 60 m=1,meqn
                amdq(i,m) = 0.d0
   60           continue
             go to 200
             endif
c
         rho1 = qr(i-1,1) + wave(i,1,1)
         rhou1 = qr(i-1,2) + wave(i,2,1)
         s1 = rhou1/rho1 - aa  !# u-c to right of 1-wave
         if (s0.lt.0.d0 .and. s1.gt.0.d0) then
c            # transonic rarefaction in the 1-wave
	     sfract = s0 * (s1-s(i,1)) / (s1-s0)
	   else if (s(i,1) .lt. 0.d0) then
c	     # 1-wave is leftgoing
	     sfract = s(i,1)
	   else
c	     # 1-wave is rightgoing
             sfract = 0.d0   !# this shouldn't happen since s0 < 0
	   endif
	 do 135 m=1,meqn
	    amdq(i,m) = sfract*wave(i,m,1)
  135       continue
c
c        # check 2-wave:
c        ---------------
c
	 s3 = ql(i,2)/ql(i,1) + aa   !# u+c in right state
         rho2 = ql(i,1) - wave(i,1,2)
         rhou2 = ql(i,2) - wave(i,2,2)
         s2 = rhou2/rho2 + aa   !# u+c to left of 2-wave
         if (s2 .lt. 0.d0 .and. s3.gt.0.d0) then
c            # transonic rarefaction in the 2-wave
	     sfract = s2 * (s3-s(i,2)) / (s3-s2)
	   else if (s(i,2) .lt. 0.d0) then
c            # 2-wave is leftgoing
	     sfract = s(i,2)
	   else 
c            # 2-wave is rightgoing
	     go to 200
	   endif
c
	 do 160 m=1,meqn
	    amdq(i,m) = amdq(i,m) + sfract*wave(i,m,2)
  160       continue
  200    continue
c
c     # compute the rightgoing flux differences:
c     # df = SUM s*wave   is the total flux difference and apdq = df - amdq
c
      do 220 m=1,meqn
         do 220 i = 2-mbc, mx+mbc
            df = 0.d0
            do 210 mw=1,mwaves
               df = df + s(i,mw)*wave(i,m,mw)
  210          continue
            apdq(i,m) = df - amdq(i,m)
  220       continue
c
  900 continue
c
      return
      end
