HoaReflect | SuperCollider 3.13.0 Help

Description

Mirror a Higher Order Ambisonic signal (HOA).

Class Methods

HoaReflect.ar(in, reflect: 'reflect', order)

Arguments:

in	The input signal.
reflect	Keyword argument for reflection. See discussion below.
order	Ambisonic order.

Discussion:

A variety of reflection transforms are offered:

keyword	mirror
`\reflect`	Mirror across the origin. Equivalent to: `\flip * \flop * \flap`.¹
`\flip`	Mirror in the y-axis.²
`\flop`	Mirror in the x-axis.³
`\flap`	Mirror in the z-axis.⁴
`\CondonShortleyPhase`	Condon-Shortley Phase. Equivalent to: `\flip * \flop`.
`\origin`	Synonym for `\reflect`.
`\x`	Synonym for `\flop`.
`\y`	Synonym for `\flip`.
`\z`	Synonym for `\flap`.

Inherited class methods

Instance Methods

Inherited instance methods

Examples

Mirror in the y-axis

// Inspect the ATK's speed of sound reference
"Speed of sound: % m/s".format(AtkHoa.speedOfSound);

// Inspect the ATK's reference radius
"Reference radius: % m".format(AtkHoa.refRadius);

// Inspect the ATK's channel/coefficient ordering
"Coefficient ordering: %".format(AtkHoa.ordering);

// Inspect the ATK's channel/coefficient ordering
"Coefficient normalisation: %".format(AtkHoa.normalisation);

// simple test...

// boot rt server
s.boot;

// choose Ambisonic order
~order = 1
~order = 2
~order = 3

// choose an outbus, if need be
~outbus = 0

// open scope
s.scope(~order.asHoaOrder.size, ~outbus);

// audition
(
{
    // saw params
    var freq = 110.0;
    var gain = -12;

// azimuth & elevation
    var theta;  // modulate, below
    var phi = 0.0;
    var thetaRate = 0.25;

// radius
    // var radius = 1.0;  // inside reference radius
    var radius = 1.5;  // at reference radius
    // var radius = 2.0;  // beyond reference radius

// delay
    var delay = 0.25;

// signals
    var sig;
    var sigHoa;
    var sigHoaDel;

theta = LFTri.kr(thetaRate, mul: pi/2);

sig = Saw.ar(freq, gain.dbamp);

// encode
    sigHoa = HoaEncodeDirection.ar(sig, theta, phi, radius, ~order);

// mirror and delay
    sigHoaDel = DelayN.ar(
        HoaReflect.ar(sigHoa, \flip, ~order),
        delay,
        delay
    );

// out
    (sigHoa + sigHoaDel) / 2
}.play(outbus: ~outbus)
)

// quit rt server
s.quit

[1] - HOA transform equivalent to FoaXformerMatrix: *newMirrorO.

[2] - HOA transform equivalent to FoaXformerMatrix: *newMirrorY.

[3] - HOA transform equivalent to FoaXformerMatrix: *newMirrorX.

[4] - HOA transform equivalent to FoaXformerMatrix: *newMirrorZ.

helpfile source: /Library/Application Support/SuperCollider/downloaded-quarks/atk-sc3/HelpSource/Classes/HoaReflect.schelp
link::Classes/HoaReflect::

HoaReflect : HoaUGen : Object Extension