VSTPluginNodeProxyController | SuperCollider 3.13.0 Help

Description

This class is used to control a specific VSTPlugin instance in a NodeProxy, so you can open plugins, automate parameters, change programs, send MIDI messages, etc.

Have a look at the examples at the bottom!

NOTE: Don't use any NodeProxy crossfading methods, like NodeProxy: -xset, because this would close the actual VST plugin and invalidate the corresponding controller.

(The reason is that JITLib implements crossfading by creating a new Synth on the Server and destroying the old one.)

WARNING: NodeProxy: -<<> and NodeProxy: -<>> call xset internally. Use set(\in, ...) instead!

NodeProxy roles

To use VSTPlugin in a NodeProxy, you have to use one the following NodeProxy roles:

\vst: a UGen graph function containing one or more VSTPlugin instances.Ndef(\test, \vst -> { VSTPlugin.ar(nil, 2) });
\vstDef: the name of a SynthDef containing one or more VSTPlugin instancesSynthDef(\vsti, { |out| Out.ar(out, VSTPlugin.ar(nil, 2)) }).add; Ndef(\test, \vstDef -> \vsti);
\vstFilter: like \filter (use the proxy`s own bus as the input)Ndef(\vst)[0] = { WhiteNoise.ar(0.1) ! 2 }; Ndef(\vst)[1] = \vstFilter -> { |in| VSTPlugin.ar(in, 2) };

Class Methods

VSTPluginNodeProxyController.new(proxy, index: 0, id, wait: -1)

Create a new VSTPluginNodeProxyController for a given NodeProxy.

Arguments:

proxy	the NodeProxy.
index	the source index.
id	a Symbol which uniquely identifies the VSTPlugin in the SynthDef. NOTE: If this is the only VSTPlugin instance in the SynthDef, the `id` argument can be omitted.
wait	the default wait time, see VSTPluginController: -wait.

Discussion:

Initially, no VST plugin is loaded and the UGen is automatically bypassed (i.e. the input is just passed through).

VSTPluginNodeProxyController.collect(proxy, index: 0, ids, wait: -1)

Same as -new, but returns an Event of VSTPluginNodeProxyControllers, with their IDs used as keys. This is useful if you have a SynthDef containing several VSTPlugin instances.

Arguments:

proxy	the NodeProxy, see -new
index	the source index
ids	an Array of IDs referring to VSTPlugin instances in the SynthDef, or `nil` (= collect all).
wait	the default wait time, see VSTPluginController: -wait.

Discussion:

Examples

VSTPlugin.search;

// ------------
// a) Filter white noise through a VST plugin
(
Ndef(\test, \vst -> { VSTPlugin.ar(WhiteNoise.ar(0.1) ! 2, 2) }).play;

~fx = VSTPluginNodeProxyController(Ndef(\test)).open("GChorus", editor: true, action: _.set('R Phase', 0.3, \Mix, 0.5));
)

~fx.editor; // open the VST plugin editor

// automate parameters with a Pbind of type \vst_set
(
Pdef(\auto, Pbind(
    \type, \vst_set,
    \vst, ~fx, // VSTPluginNodeProxyController
    \params, [\Depth, \Freq],
    \Depth, Pwhite(0.1, 0.9),
    \Freq, Pseq([0.1, 0.2, 0.5, 0.9], inf),
    \dur, Prand([0.25, 0.5, 1], inf)
)).play;
)

Pdef(\auto).stop;
Pdef(\auto).play;

// ------------
// b) For more flexibility, let's split it into seperate sources; the first source is filtered by the second source
(
Ndef(\test)[0] = { WhiteNoise.ar(0.1) ! 2 };
Ndef(\test)[1] = \vstFilter -> { |in| VSTPlugin.ar(in, 2) };
Ndef(\test).play;

// We want to control the source at index 1!
~fx = VSTPluginNodeProxyController(Ndef(\test), 1).open("GChorus", editor: true);
)

// ------------
// c) Let's go one step further and use seperate NodeProxies
(
Ndef(\white, { WhiteNoise.ar(0.1) ! 2 });
Ndef(\fx, \vst -> { VSTPlugin.ar(\in.ar(0 ! 2), 2) });
// Route \white to \fx. (Don't use '<>>' or '<<>'!)
Ndef(\fx).set(\in, Ndef(\white));
Ndef(\fx).play;

~fx = VSTPluginNodeProxyController(Ndef(\fx)).open("GChorus", editor: true);
)

// Now it's possible to change the routing on the fly:
(
Ndef(\pink, { PinkNoise.ar(0.1) ! 2 });
Ndef(\fx).set(\in, Ndef(\pink));
)

// ------------
// d) If you look at the last example, you might notice that the VSTPlugin function will always be the same, so it makes sense to use a SynthDef instead! Most of the time the following SynthDefs should be sufficient:

(
// mono insert FX
SynthDef(\vst_fx_mono, { |out| Out.ar(out, VSTPlugin.ar(\in.ar(0), 1)) }).add;

// stereo insert FX
SynthDef(\vst_fx_stereo, { |out| Out.ar(out, VSTPlugin.ar(\in.ar(0 ! 2), 2)) }).add;

// VST instrument (stereo)
SynthDef(\vsti, { |out| Out.ar(out, VSTPlugin.ar(nil, 2)) }).add;
)

// Now let's rewrite c) by using the \vstDef role:
(
Ndef(\white, { WhiteNoise.ar(0.1) ! 2 });
Ndef(\fx, \vstDef -> \vst_fx_stereo);
// Route \white to \fx. (Don't use '<>>' or '<<>'!)
Ndef(\fx).set(\in, Ndef(\white));
Ndef(\fx).play;

~fx = VSTPluginNodeProxyController(Ndef(\fx)).open("GChorus", editor: true);
)

// ------------
// e) Creating a VST instrument is simple:
(
// This needs the \vsti SynthDef above!
Ndef(\inst, \vstDef -> \vsti).play;
~inst = VSTPluginNodeProxyController(Ndef(\inst)).open("Dexed", editor: true, action: _.program_(1));
Ndef(\inst).play;
)

~inst.editor;

// Now play some notes with a Pbind of type \vst_midi
(
Pdef(\seq, Pbind(
    \type, \vst_midi,
    \vst, ~inst,
    \midinote, Pseq(#[0, 2, 4, 7], inf) + Pwhite(-12, 12).stutter(Pwhite(4, 16)) + 60,
    \dur, Prand(#[0.125, 0.25, 0.5], inf),
    \legato, Pexprand(0.5, 1.0, inf),
    \amp, Pexprand(0.5, 1.0, inf)
)).play;
)
// Pause/resume/end the Pbind.
Pdef(\seq).stop;
Pdef(\seq).play;

helpfile source: /Library/Application Support/SuperCollider/Extensions/VSTPlugin-0.5.4/HelpSource/Classes/VSTPluginNodeProxyController.schelp
link::Classes/VSTPluginNodeProxyController::

VSTPluginNodeProxyController : VSTPluginController : Object
Extension

Description

NodeProxy roles

Class Methods

VSTPluginNodeProxyController.new(proxy, index: 0, id, wait: -1)

Arguments:

Discussion:

VSTPluginNodeProxyController.collect(proxy, index: 0, ids, wait: -1)

Arguments:

Discussion:

Inherited class methods

Instance Methods

.sendMsg(cmd ... args)

.proxy

Inherited instance methods

Undocumented instance methods

.checkIfStarted(synth)

.initProxyAndCondition(inProxy)

Examples

VSTPluginNodeProxyController : VSTPluginController : Object Extension

VSTPluginNodeProxyController.new(proxy, index: 0, id, wait: -1)

Arguments:

Discussion:

VSTPluginNodeProxyController.collect(proxy, index: 0, ids, wait: -1)

Arguments:

Discussion:

.sendMsg(cmd ... args)

.proxy

.checkIfStarted(synth)

.initProxyAndCondition(inProxy)

VSTPluginNodeProxyController : VSTPluginController : Object
Extension