HoaNFProx | SuperCollider 3.13.0 Help

Description

Higher Order Ambisonic signal (HOA) near-field effect (NFE) proximity transformer.

Class Methods

HoaNFProx.ar(in, order)

Arguments:

in	The input signal.
order	Ambisonic order.

Discussion:

HoaNFProx translates an input HOA signal where refRadius = AtkHoa.refRadius to refRadius = inf.

This transform offers an HOA equivalent to FoaProximity where distance = AtkHoa.refRadius, in the first order case.

NOTE: This operation may be used to decode signals encoded as HOA with NFE to FOA or third party Ambisonic signal sets.

WARNING: The near-field effect proximity transformer is inherently numerically unstable and requires the use of signal pre-conditioned input to avoid overflow. In many cases, the use of HoaNFCtrl is advised, instead.

Inherited class methods

Instance Methods

Inherited instance methods

Examples

Decode from HOA1 with NFE to FOA

// Inspect the ATK's speed of sound reference
"Speed of sound: % m/s".format(AtkHoa.speedOfSound);

// Inspect the ATK's reference radius
"Reference radius: % m".format(AtkHoa.refRadius);

// Inspect the ATK's channel/coefficient ordering
"Coefficient ordering: %".format(AtkHoa.ordering);

// Inspect the ATK's channel/coefficient ordering
"Coefficient normalisation: %".format(AtkHoa.normalisation);

// simple test...

// boot rt server
s.boot;

// choose Ambisonic order
~order = 1  // match FOA, first order!

// choose an outbus, if need be
~outbus = 0

// open scope
s.scope(~order.asHoaOrder.size, ~outbus);

// encoding angles
// azimuth & elevation
~theta = 0.0;
~phi = 0.0;

// explicitly set encoding radius
// i.e., radius != AtkHoa.refRadius
~encRadius = 2.0;  // > AtkHoa.refRadius
~encRadius = 1.5;  // = AtkHoa.refRadius
~encRadius = 1.0;  // < AtkHoa.refRadius

// audition
(
{
    // saw params
    var freq = 110.0;
    var gain = -12;

var sig;
    var hoa;

sig = Saw.ar(freq, gain.dbamp);  // saw
    // sig = SinOsc.ar(freq, mul: gain.dbamp);  // sine

// HOA encoding, refRadius = AtkHoa.refRadius (= 1.5)
    hoa = HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order);  // no need to precondition sig!

// FOA decoding, refRadius = inf
    HoaDecodeMatrix.ar(
        HoaNFProx.ar(
            HPF.ar(hoa, freq/3),  // precondition sig, i.e., "make safe" for proximity (HOA1)
            ~order
        ),
        HoaMatrixDecoder.newFormat(\fuma, ~order)  // from atk to fuma
    );

}.play(outbus: ~outbus)
)

// quit rt server
s.quit

helpfile source: /Library/Application Support/SuperCollider/downloaded-quarks/atk-sc3/HelpSource/Classes/HoaNFProx.schelp
link::Classes/HoaNFProx::

HoaNFProx : HoaUGen : Object Extension