HoaRTT | SuperCollider 3.13.0 Help

Description

Rotate a Higher Order Ambisonic signal (HOA) around the z, x and y axes.

Compound rotations applied in sequential order: rotate, tilt, tumble.

NOTE: Extrinsic, "laboratory-fixed" axes.

Class Methods

HoaRTT.ar(in, rotate: 0, tilt: 0, tumble: 0, order)

Arguments:

in	The input signal.
rotate	Rotation angle around z-axis, in radians.
tilt	Rotation angle around x-axis, in radians.
tumble	Rotation angle around y-axis, in radians.
order	Ambisonic order.

Discussion:

Transform is equivalent to HoaRotate followed by HoaTilt and then HoaTumble.

Inherited class methods

Instance Methods

Inherited instance methods

Examples

Rotate around z, x and y axes

// Inspect the ATK's speed of sound reference
"Speed of sound: % m/s".format(AtkHoa.speedOfSound);

// Inspect the ATK's reference radius
"Reference radius: % m".format(AtkHoa.refRadius);

// Inspect the ATK's channel/coefficient ordering
"Coefficient ordering: %".format(AtkHoa.ordering);

// Inspect the ATK's channel/coefficient ordering
"Coefficient normalisation: %".format(AtkHoa.normalisation);

// simple test...

// boot rt server
s.boot;

// choose Ambisonic order
~order = 1
~order = 2
~order = 3

// choose an outbus, if need be
~outbus = 0

// open scope
s.scope(~order.asHoaOrder.size, ~outbus);

// audition
(
{
    // saw params
    var freq = 110.0;
    var gain = -12;

// azimuth & elevation
    var theta = 0.0;
    var phi = 0.0;
    var rotateRate = 0.25;

// radius
    // var radius = 1.0;  // inside reference radius
    var radius = 1.5;  // at reference radius
    // var radius = 2.0;  // beyond reference radius

// signals
    var sig;
    var sigHoa;
    var sigHoaRot;
    var rtt;

sig = Saw.ar(freq, gain.dbamp);

rtt = LFSaw.kr(LFNoise2.kr(1.dup(3)).range(0.75 * rotateRate, 1.25 * rotateRate), mul: pi);

// encode
    sigHoa = HoaEncodeDirection.ar(sig, theta, phi, radius, ~order);

// rotate
    sigHoaRot = HoaRTT.ar(
        sigHoa,
        rtt[0],
        rtt[1],
        rtt[2],
        ~order
    );

// out
    sigHoaRot
}.play(outbus: ~outbus)
)

// quit rt server
s.quit

helpfile source: /Library/Application Support/SuperCollider/downloaded-quarks/atk-sc3/HelpSource/Classes/HoaRTT.schelp
link::Classes/HoaRTT::

HoaRTT : HoaUGen : Object Extension