HoaTilt | SuperCollider 3.13.0 Help

Subclasses: HoaRoll

Description

Rotate a Higher Order Ambisonic signal (HOA) around the x-axis.

Class Methods

HoaTilt.ar(in, angle: 0, order)

Arguments:

in	The input signal.
angle	Rotation angle, in radians.
order	Ambisonic order.

Discussion:

A rotation of pi/2 will rotate a source at [pi/2, 0] to [0, pi/2].

Inherited class methods

Instance Methods

Inherited instance methods

Examples

Rotate around the x-axis

// Inspect the ATK's speed of sound reference
"Speed of sound: % m/s".format(AtkHoa.speedOfSound);

// Inspect the ATK's reference radius
"Reference radius: % m".format(AtkHoa.refRadius);

// Inspect the ATK's channel/coefficient ordering
"Coefficient ordering: %".format(AtkHoa.ordering);

// Inspect the ATK's channel/coefficient ordering
"Coefficient normalisation: %".format(AtkHoa.normalisation);

// simple test...

// boot rt server
s.boot;

// choose Ambisonic order
~order = 1
~order = 2
~order = 3

// choose an outbus, if need be
~outbus = 0

// open scope
s.scope(~order.asHoaOrder.size, ~outbus);

// audition
(
{
    // saw params
    var freq = 110.0;
    var gain = -12;

// azimuth & elevation
    var theta = pi/2;
    var phi = 0.0;
    var rotateRate = 0.25;

// radius
    // var radius = 1.0;  // inside reference radius
    var radius = 1.5;  // at reference radius
    // var radius = 2.0;  // beyond reference radius

// signals
    var sig;
    var sigHoa;
    var sigHoaRot;

sig = Saw.ar(freq, gain.dbamp);

// encode
    sigHoa = HoaEncodeDirection.ar(sig, theta, phi, radius, ~order);

// rotate
    sigHoaRot = HoaTilt.ar(
        sigHoa,
        LFSaw.kr(rotateRate, mul: pi),
        ~order
    );

// out
    sigHoaRot
}.play(outbus: ~outbus)
)

// quit rt server
s.quit

helpfile source: /Library/Application Support/SuperCollider/downloaded-quarks/atk-sc3/HelpSource/Classes/HoaTilt.schelp
link::Classes/HoaTilt::

HoaTilt : HoaUGen : Object Extension