Near-Field Effect (NFE) | SuperCollider 3.13.0 Help

This document provides a very short overview of the near-field effect (NFE). A variety of simple HOA example implementations follow.

The Near-Field Effect

We'll by briefly reviewing the near-field effect (NFE) in the context of FOA and HOA.

The near-field effect (NFE) has been formally included within the Ambisonic framework since its initial design. In the classic days of Ambisonic hardware, users usually only directly interfaced this aspect of Ambisonics through the use of:

the soundfiled microphone on the encoding side
Near-Field Compensation (NFC) loudspeaker distance correction filtering on the decoding side

The ATK's FOA toolset includes NFE radial filters in their classic Ambisonic form. In the FOA context a travelling wave encoded with all real, aka basic, coefficients represents a planewave. The ATK also names this travelling wave as a basic wave, because of the use of basic, real coefficient encoding. SuperCollider's PanB is a basic, planewave encoder.

An Ambisonic system's reference radius is the radius at which a basic wave is encoded. So the reference radius locates the radius at which the system's encoding uses real numbers only.

For FOA, the reference radius is infinity. A wave arriving from infinity is a planewave, which is why FOA's basic wave is a planewave.

On receiving a basic wave, the FOA proximity filter add curvature to the wavefront, converting it from a planewave to a spherical wave¹ at a defined radius.²

The FOA near-field compensation filter returns the inverse of the FOA proximity filter, and given the same radial argument undoes the curvature to the wavefront that had been applied. In the context of loudspeaker decoding, the near-field compensation filter is intended to remove the wavefront add by the nearness of the loudspeakers. I.e., near-field compensation filter removes the curve added by the physical nearness of real monitors in the real world.

When FoaNFC and FoaProximity are used together, we can reach inside a soundfield and apply processing at a specified radius. The one possible network looks like this:

Source extraction

Parameters theta and phi supply the look direction. The angle argument continuously transforms the image between:

0 : original unchanged soundfield
pi/2 : spherical wave sampled at distance

The term radial beamforming is used to describe this soundfield operation. With radial beamforming the soundfield can be decomposed and recomposed as spherical waves, at whatever radius we choose.

HOA

It could be argued that the greatest innovation in Daniel's reframing of Ambisonics in a higher order context is the translation of the basic wave to a radius other than infinity.

If we'd like to think in a real world way, this is equivalent to pre-filtering a soundfield with the near-field compensation filter in anticipation of decoding to loudspeakers located at a pre-determined radius. This radius is the reference radius. We can view this as the anticipated loudspeakers finishing off the synthesis of the curve of the encoded waves by physically adding the remaining curve.

This is all good, but the true genius is the inclusion of a the near-field effect control filter, which combines the near-field compensation and proximity filter into a single block. The arrangement is as illustrated above, but without the inclusion of focus. Also, instead of having a single distance argument, there are two, one for each filter. Doing so makes it very easy to translate the reference radius. In other words, we can move where basic waves are encoded, which easily facilitates radial beamforming.

If we prefer thinking in terms of virtual loudspeakers, changing the reference radius corresponds to moving the virtual loudspeakers. This then corresponds to moving the soundfield sampling radius when it comes to decomposition and recomposition.

________________

As part of the ATK's HOA toolset we have three principal filters tasked with the near-field effect.

Each of these has a distinct role:

Near-Field Effect Distance filter (NFE-D): HoaNFDist transforms a basic wave into a planewave.
Signal: *hoaDist is the associated FIR kernel designer.
Near-Field Effect Proximity filter (NFE-P): HoaNFProx transforms a planewave into a basic wave.
Note, an associated FIR kernel designer is not provided.³
Near-Field Effect Control filter (NFE-C): HoaNFCtrl transforms a basic wave into a spherical wave at another radius.⁴
Signal: *hoaCtrl is the associated FIR kernel designer.

NOTE: In NFC-HOA encoding, planewaves and spherical waves are referenced to a real number valued reference radius.

E.g., a planewave in NFC-HOA is not a basic wave. Conversly, complex coefficients are required to encode and synthesize a planewave.

Unlike their FOA equivalents, HoaNFDist and HoaNFProx do not have an exposed distance argument. By default, the distance argument is set internally to the ATK's reference radius for HOA, 1.5 meters.⁵ Doing so enforces the ATK's NFE encoding convention.

HoaNFCtrl has two arguments, encoding radius and decoding radius, which allows comprehensive control of the near-field effect in HOA.

We'll review some examples, below.

Encoding & decoding

Two examples intended to offer insight into what encoded spherical waves look like with respect to signal phase and gain.

Encode a spherical wave

For this first example we'll encode a travelling wave. The three example radii all return spherical waves. One of these, encoded at 1.5 meters, is a basic wave.

NOTE: A decoder hasn't been provided, the intention of this example is to inspect the returned HOA encoded signals for a collection of spherical waves. You'll see that for an encoding at the reference radius, when all coefficients are real, all harmonics are aligned in phase.

Observe this in the scope.

Sample a spherical wave

By sampling a soundfield at the radius a spherical wave was originally encoded, we can recover the original source.

This is called radial soundfield sampling. We look into the soundfield at a specific radius.

The look direction of the beamformer, HoaDecodeDirection, is slowly moving back and forth. This movement is what is responsible for the varing gain of the returned beam.

NOTE: The three beamshape choice offer different shaped spatial sampling windows.

// Inspect the ATK's reference radius
"Reference radius: % m".format(AtkHoa.refRadius);

// simple test...

// boot rt server
s.boot;

// choose Ambisonic order
~order = 1
~order = 2
~order = 3

// choose an outbus, if need be
~outbus = 0

// open scope
s.scope(2, ~outbus);  // view original signal & mono decode

// encoding angles
// azimuth & elevation
~theta = 0.0;
~phi = 0.0;

// explicitly set encoding radius
// i.e., radius != AtkHoa.refRadius
~encRadius = 2.0;  // > AtkHoa.refRadius
~encRadius = 1.5;  // = AtkHoa.refRadius
~encRadius = 1.0;  // < AtkHoa.refRadius

// beaming
~thetaRate = 0.125;  // modulation rate for beam look direction
~beamShape = \basic;
~beamShape = \energy;
~beamShape = \controlled;
~decRadius = ~encRadius; // explicitly set to match encoding radius

// audition
(
{
    // saw params
    var freq = 110.0;
    var gain = -12;

var sig;
    var hoa;
    var dec;

sig = Saw.ar(freq, gain.dbamp);

hoa = HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order);

dec = HoaDecodeDirection.ar(
        hoa,
        LFTri.kr(~thetaRate, mul: pi),
        ~phi,
        ~encRadius,
        ~beamShape,
        ~order
    );

[ sig,  dec];

}.play(outbus: ~outbus)
)

// quit rt server
s.quit

Beaming & nulling

Beaming and nulling transforms are spatial bandpass and bandreject filters. Instead of operating in the frequency domain, we're operating in the spatial domain.

Given the same beamshape, the beam summed with a corresponding null will return the original soundfield.

Used in this way, these two transforms allow us to easily process different parts of the soundfield in different ways. E.g., the null could be lowpass filtered and then remixed with the beam.

NOTE: As with the soundfield sampler HoaDecodeDirection example above, the beam is formed at a sampling radius.

Beamform with HoaBeam

Encode six sinusoids on the axes, then sample the soundfield with a single beam.

The beam is reencoded, so we're auditioning a virtual speaker at the beam sampling radius, which can be varied. We'll need a decoder to audition.

This is like spatially bandpass filtering the soundfield.// simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 ~order = 2 ~order = 3 // choose an outbus, if need be ~outbus = 0 // open scope s.scope(~order.asHoaOrder.size, ~outbus); // design encoding matrix ~directions = [ [0.0, 0.0], [90.0, 0.0], [180.0, 0.0], [-90.0, 0.0], [0.0, 90.0], [0.0, -90.0], ].degrad; ~matrixEncoder = HoaMatrixEncoder.newDirections(~directions, order: ~order); // explicitly set encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // beaming ~thetaRate = 0.125; // modulation rate for beam look direction ~phi = 0.0; ~beamShape = \basic; ~beamShape = \energy; ~beamShape = \controlled; // freqs ~freqs = Array.series(~directions.size, 110.0, 110.0); ~amps = Array.series(~directions.size, 1, 1).reciprocal; // audition ( { var gain = -12; var sig, hoa; sig = SinOsc.ar(~freqs, mul: gain.dbamp * ~amps); hoa = HoaNFCtrl.ar( HoaEncodeMatrix.ar(sig, ~matrixEncoder), ~encRadius, // encoding radius AtkHoa.refRadius, // reference radius ~order ); HoaBeam.ar(hoa, LFTri.kr(~thetaRate, mul: pi), ~phi, ~encRadius, ~beamShape, ~order); }.play(outbus: ~outbus) ) // quit rt server s.quit

Beamform with HoaXformMatrix

Similar to Beamform with HoaBeam, but this time beaming with a static matrix.

NOTE: Because the beaming transform matrix is a real number matrix, the beam is formed at the reference radius.

To beam at another radius, we'd have to use the technique illustrated below.

Nullform with HoaNull

Same test as above, but we form a null, instead. We are spatially rejecting part of the soundfield.// simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 ~order = 2 ~order = 3 // choose an outbus, if need be ~outbus = 0 // open scope s.scope(~order.asHoaOrder.size, ~outbus); // design encoding matrix ~directions = [ [0.0, 0.0], [90.0, 0.0], [180.0, 0.0], [-90.0, 0.0], [0.0, 90.0], [0.0, -90.0], ].degrad; ~matrixEncoder = HoaMatrixEncoder.newDirections(~directions, order: ~order); // explicitly set encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // nulling ~thetaRate = 0.125; // modulation rate for null look direction ~phi = 0.0; ~beamShape = \basic; ~beamShape = \energy; ~beamShape = \controlled; // freqs ~freqs = Array.series(~directions.size, 110.0, 110.0); ~amps = Array.series(~directions.size, 1, 1).reciprocal; // audition ( { var gain = -12; var sig, hoa; sig = SinOsc.ar(~freqs, mul: gain.dbamp * ~amps); hoa = HoaNFCtrl.ar( HoaEncodeMatrix.ar(sig, ~matrixEncoder), ~encRadius, // encoding radius AtkHoa.refRadius, // reference radius ~order ); HoaNull.ar(hoa, LFTri.kr(~thetaRate, mul: pi), ~phi, ~encRadius, ~beamShape, ~order); }.play(outbus: ~outbus) ) // quit rt server s.quit

Techniques

The Near-Field Effect Control filter (NFE-C), HoaNFCtrl has a wide number of uses in HOA. Here are a few important examples.

Decode to a 2D array

Radial encoding followed by decoding with loudspeaker near-field compensation.

When the real loudspeaker radius doesn't match the reference radius, we need to use HoaNFCtrl to reset the radial encoding.

We can view this as HoaNFCtrl finishing the radial part of the panning law, to match our actual loudspeaker array.

NOTE: This is required if we would like the NFE to properly resolve.

// Inspect the ATK's reference radius
"Reference radius: % m".format(AtkHoa.refRadius);

// simple test...

// boot rt server
s.boot;

// choose Ambisonic order
~order = 1
~order = 2
~order = 3

// choose an outbus, if need be
~outbus = 0

// encoding angles
// azimuth & elevation
~theta = 0.0;
~phi = 0.0;

// explicitly set encoding radius
// i.e., radius != AtkHoa.refRadius
~encRadius = 2.0;  // > AtkHoa.refRadius
~encRadius = 1.5;  // = AtkHoa.refRadius
~encRadius = 1.0;  // < AtkHoa.refRadius

// decoding - panto decoder
~numChans = 8;
~orientation = \flat;
~beamShape = \basic;
~beamShape = \energy;  // <-- good choice!
~beamShape = \controlled;
~match = \amp;
~match = \rms;
~match = \energy;  // <-- good choice!
~decRadius = 2.0;  // decoding / (actual) loudspeaker radius

// open scope
s.scope(~numChans, ~outbus);

// audition
(
{
    // saw params
    var freq = 110.0;
    var gain = -12;

var sig;
    var hoa;

sig = Saw.ar(freq, gain.dbamp);

// encode with NFE
    hoa = HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order);

// decode with NFE / loudspeaker near-field compensation
    HoaDecodeMatrix.ar(
        HoaNFCtrl.ar(  // NFE control
            hoa,
            AtkHoa.refRadius,
            ~decRadius,
            ~order
        ),
        HoaMatrixDecoder.newPanto(  // panto decoder
            ~numChans,
            ~orientation,
            ~beamShape,
            ~match,
            ~order
        )
    );

}.play(outbus: ~outbus)
)

// quit rt server
s.quit

Synthesize a diffuse field

Here we synthesize a soundfield that is diffuse at a specified encoding radius.⁶ // Inspect the ATK's reference radius "Reference radius: % m".format(AtkHoa.refRadius); // simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 ~order = 2 ~order = 3 // choose an outbus, if need be ~outbus = 0 // open scope s.scope(~order.asHoaOrder.size, ~outbus); // explicitly set encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 10.0; // >> AtkHoa.refRadius ~encRadius = 5.0; // > AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // audition ( { // params var gain = -12; var hoa; // diffuse field (synthesized at AtkHoa.refRadius) hoa = ~order.asHoaOrder.size.collect({ BrownNoise.ar(gain.dbamp) }); // encode with NFE HoaNFCtrl.ar( // NFE control hoa, ~encRadius, AtkHoa.refRadius, ~order ); }.play(outbus: ~outbus) ) // quit rt server s.quit

Translate to a new radius

Translate from source radius to target radius. A very useful trick!// Inspect the ATK's reference radius "Reference radius: % m".format(AtkHoa.refRadius); // simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 ~order = 2 ~order = 3 // choose an outbus, if need be ~outbus = 0 // open scope s.scope(~order.asHoaOrder.size, ~outbus); // encoding angles // azimuth & elevation ~theta = 0.0; ~phi = 0.0; // explicitly set (source) encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // target (translation) radius ~reEncRadius = 3.0; // re-encoding radius > AtkHoa.refRadius ~reEncRadius = 1.5; // re-encoding radius = AtkHoa.refRadius ~reEncRadius = 1.0; // re-encoding radius < AtkHoa.refRadius // audition ( { // saw params var freq = 110.0; var gain = -12; var sig; var hoa; sig = Saw.ar(freq, gain.dbamp); // encode with NFE hoa = HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order); // re-encode NFE HoaNFCtrl.ar( hoa, ~reEncRadius, ~encRadius, ~order ); }.play(outbus: ~outbus) ) // quit rt server s.quit

Modulate at radius

The use of two HoaNFCtrl transformers offers the possibility of modulation at a given radius.

The soundfield is decomposed into a collection of samples at a certain radius. These are then modulated. The soundfield is re-encoded, and samples are returned to their original radius.

If we wish to granulate at a radius other than the reference radius, for instance, this example illustrates how to do so.// Inspect the ATK's reference radius "Reference radius: % m".format(AtkHoa.refRadius); // simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 ~order = 2 ~order = 3 // choose an outbus, if need be ~outbus = 0 // encoding angles // azimuth & elevation ~theta = 0.0; ~phi = 0.0; // explicitly set encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // decoding / re-encoding - spherical design (A/B-format) ~numChans = 24; ~beamShape = \basic; ~beamShape = \energy; ~beamShape = \controlled; ~sphDesign = TDesign.newHoa(~numChans, order: ~order); // modulation ~modRate = 20.0; ~modRate = 10.0; ~modRate = 5.0; // open scope s.scope(~order.asHoaOrder.size, ~outbus); // audition ( { // saw params var freq = 110.0; var gain = -12; var sig; var hoa; var aformat; sig = Saw.ar(freq, gain.dbamp); // encode with NFE hoa = HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order); // decode with NFE aformat = HoaDecodeMatrix.ar( HoaNFCtrl.ar( // NFE control - decode at encoding radius, the "look" radius hoa, AtkHoa.refRadius, ~encRadius, ~order ), HoaMatrixDecoder.newSphericalDesign( // a-format decoder ~sphDesign, ~beamShape, ~order ) ); // modulate amplitude of "virtual loudspeakers" - in a-format aformat = aformat * ~numChans.collect({ LFNoise2.ar(~modRate).range }); // aformat = aformat * ~numChans.collect({ LFNoise2.ar(~modRate) }); // re-encode with NFE HoaNFCtrl.ar( // NFE control - re-encode at encoding radius, the "look" radius HoaEncodeMatrix.ar( aformat, HoaMatrixEncoder.newSphericalDesign( // a-format encoder ~sphDesign, ~beamShape, ~order ) ), ~encRadius, AtkHoa.refRadius, ~order ); }.play(outbus: ~outbus) ) // quit rt server s.quit

Format Exchange

If you haven't already, do review Ambisonic Format Exchange.

Encode from FOA

The example using HoaNFDist is equivalent to the one found here.// Inspect the ATK's reference radius "Reference radius: % m".format(AtkHoa.refRadius); // simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 // match FOA, first order! // choose an outbus, if need be ~outbus = 0 // open scope s.scope(~order.asHoaOrder.size, ~outbus); // encoding angles // azimuth & elevation ~theta = 0.0; ~phi = 0.0; // explicitly set encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // audition ( { // saw params var freq = 110.0; var gain = -12; var sig; var foa; sig = Saw.ar(freq, gain.dbamp); // saw // sig = SinOsc.ar(freq, mul: gain.dbamp); // sine // FOA encoding, refRadius = inf foa = FoaProximity.ar( // FOA radial encoding FoaPanB.ar( // FOA angular encoding HPF.ar(sig, freq/3), // precondition sig, i.e., "make safe" for proximity ~theta, ~phi ), ~encRadius ); // HOA re-encoding, refRadius = AtkHoa.refRadius (= 1.5) HoaNFDist.ar( HoaEncodeMatrix.ar( foa, HoaMatrixEncoder.newFormat(\fuma, ~order) // from fuma to atk ), ~order ); // // compare to direct HOA1 encoding // HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order); // no need to precondition sig! }.play(outbus: ~outbus) ) // quit rt server s.quit

Decode to FOA

The example using HoaNFProx is equivalent to the one found here.// Inspect the ATK's reference radius "Reference radius: % m".format(AtkHoa.refRadius); // simple test... // boot rt server s.boot; // choose Ambisonic order ~order = 1 // match FOA, first order! // choose an outbus, if need be ~outbus = 0 // open scope s.scope(~order.asHoaOrder.size, ~outbus); // encoding angles // azimuth & elevation ~theta = 0.0; ~phi = 0.0; // explicitly set encoding radius // i.e., radius != AtkHoa.refRadius ~encRadius = 2.0; // > AtkHoa.refRadius ~encRadius = 1.5; // = AtkHoa.refRadius ~encRadius = 1.0; // < AtkHoa.refRadius // audition ( { // saw params var freq = 110.0; var gain = -12; var sig; var hoa; sig = Saw.ar(freq, gain.dbamp); // saw // sig = SinOsc.ar(freq, mul: gain.dbamp); // sine // HOA encoding, refRadius = AtkHoa.refRadius (= 1.5) hoa = HoaEncodeDirection.ar(sig, ~theta, ~phi, ~encRadius, ~order); // no need to precondition sig! // FOA decoding, refRadius = inf HoaDecodeMatrix.ar( HoaNFProx.ar( HPF.ar(hoa, freq/3), // precondition sig, i.e., "make safe" for proximity (HOA1) ~order ), HoaMatrixDecoder.newFormat(\fuma, ~order) // from atk to fuma ); }.play(outbus: ~outbus) ) // quit rt server s.quit

[1] - Many users will refer to this as an encoded point source.

[2] - FoaProximity argument distance.

[3] - Too many big numbers!

[4] - A spherical wave with complex coefficients.

[5] - If desired, the system reference radius may be changed: AtkHoa: *setRefRadius.

[6] - Arguably, one might consider a soundfield to be considered diffuse only if it is composed of planewaves. If that is your preference, then HoaNFDist is the tool for the job.

helpfile source: /Library/Application Support/SuperCollider/downloaded-quarks/atk-sc3/HelpSource/Guides/HOA-NFE.schelp
link::Guides/HOA-NFE::

Near-Field Effect (NFE)Extension

Near-Field Effect (NFE)
Extension